学习ADO.NET时，你可能会遇到ADO.NET修改数据问题，这里将介绍ADO.NET修改数据问题的解决方法，在这里拿出来和大家分享一下。存储过程可以接受数据作为输入参数并可以返回数据作为输出参数、结果集或返回值。 下面的示例演示 ADO.NET 如何发送和接收输入参数、输出参数及返回值。 该示例将一条新记录插入到一个表中，该表中的主键列为 SQL Server 数据库中的标识列。

#T#如果您通过 SqlDataAdapter 使用 SQL Server 存储过程来编辑或删除数据，则应确保不在存储过程定义中使用 SET NOCOUNT ON。 这将使返回的受影响的行数为零，DataAdapter 会将其解释为并发冲突。 在这种情况下，将引发 DBConcurrencyException。此示例使用以下存储过程将一个新类别插入到 Northwind 的“类别”表。 存储过程获取 CategoryName 列中的值作为输入参数，并使用 SCOPE_IDENTITY() 函数来检索标识字段 CategoryID 的新值，然后在输出参数中返回该新值。 RETURN 语句使用 @@ROWCOUNT 函数返回所插入的行数。

CREATE PROCEDURE dbo.InsertCategory  
@CategoryName nvarchar(15),  
@Identity int OUT  
AS  
INSERT INTO Categories (CategoryName) VALUES(@CategoryName)  
SET @Identity = SCOPE_IDENTITY()  
RETURN @@ROWCOUNT 

下面的ADO.NET修改数据代码示例使用上面显示的 InsertCategory 存储过程作为 SqlDataAdapter 的 InsertCommand 的来源。 如果在将记录插入到数据库后调用 SqlDataAdapter 的 Update 方法，DataSet 中将会反映出 @Identity 输出参数。 此代码还会检索返回值。在使用 OleDbDataAdapter 时，必须在其他参数之前先使用 ReturnValue 的ParameterDirection 指定参数。

Private Sub ReturnIdentity(ByVal connectionString As String)  
Using connection As SqlConnection = New SqlConnection( _  
 connectionString)  
 
' Create a SqlDataAdapter based on a SELECT query.  
Dim adapter As SqlDataAdapter = New SqlDataAdapter( _  
 "SELECT CategoryID, CategoryName FROM dbo.Categories", _  
 connection)  
 
' Create a SqlCommand to execute the stored procedure.   
adapter.InsertCommand = New SqlCommand("dbo.InsertCategory", _  
 connection)  
adapter.InsertCommand.CommandType = CommandType.StoredProcedure  
 
' Create a parameter for the ReturnValue.  
Dim parameter As SqlParameter = _ 
 adapter.InsertCommand.Parameters.Add( _  
"@RowCount", SqlDbType.Int)  
parameter.Direction = ParameterDirection.ReturnValue  
 
' Create an input parameter for the CategoryName.  
' You do not need to specify direction for input parameters.  
adapter.InsertCommand.Parameters.Add( _  
"@CategoryName", SqlDbType.NChar, 15, "CategoryName")  
 
' Create an output parameter for the new identity value.  
parameter = adapter.InsertCommand.Parameters.Add( _  
"@Identity", SqlDbType.Int, 0, "CategoryID")  
parameter.Direction = ParameterDirection.Output  
 
' Create a DataTable and fill it.  
Dim categories As DataTable = New DataTable  
adapter.Fill(categories)  
 
' Add a new row.  
Dim newRow As DataRow = categories.NewRow()  
newRow("CategoryName") = "New Category"  
categories.Rows.Add(newRow)  
 
' Update the database.  
adapter.Update(categories)  
 
' Retrieve the ReturnValue.  
Dim rowCount As Int32 = _ 
 CInt(adapter.InsertCommand.Parameters("@RowCount").Value)  
 
Console.WriteLine("ReturnValue: {0}", rowCount.ToString())  
Console.WriteLine("All Rows:")  
Dim row As DataRow  
For Each row In categories.Rows  
Console.WriteLine("{0}: {1}", row(0), row(1))  
Next  
End Using  
End Sub